RSI-AREA.советник

да чуть не забыл,если что пишите на мыло dmitry-dobrynin@rambler.ru

//+------------------------------------------------------------------+
//|                                                 RSI-AREA.mq4     |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net// |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net//"
 
extern int RSIPeriod=13;
extern int AreaCondition=300;
 
 
 
 
  
int start()
{  
   static int RSIAreaShift=0;
   int cnt, shift;
   double RSIOpen, RSIArea, RSICurrent, RSILocalMin, RSILocalMax, value;
 
   
 
   if(OrdersTotal()<1)
 
   {  
      RSIArea = RSIAreaFunc(RSIAreaShift, RSIPeriod, 0);
 
      if(RSIArea<-AreaCondition)
      {  
      OrderSend(Symbol(),OP_BUY,1.0,Ask,3,0.0,0.0);
      RSIOpen = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
      }  
      
      if(RSIArea>AreaCondition)
      {  
      OrderSend(Symbol(),OP_SELL,1.0,Bid,3,0.0,0.0);
      RSIOpen = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
 
      }
      
      RSIAreaShift=0;
      return(0);
   }
      
// =================================================================
      
      RSICurrent = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
      if(RSIOpen>50 && RSICurrent>50) return(0);
      if(RSIOpen<50 && RSICurrent<50) return(0);
        
      RSILocalMin = RSICurrent;
      RSILocalMax = RSICurrent;
      
for(shift=1; shift<RSIAreaShift; shift++)
{  
      value = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, shift);
      if(value<RSILocalMin && RSIArea>0) RSILocalMin=value;
      if(value>RSILocalMax && RSIArea<0) RSILocalMax=value;
       
      for(cnt=OrdersTotal()-1; cnt>=0; cnt--)
      {  
      OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
      
         if(OrderSymbol()==Symbol())
         {  
         
            if(OrderType()==OP_BUY)
            {  
            if(RSILocalMax >= (RSICurrent+4) && RSILocalMax>50)
               {
               OrderClose(OrderTicket(),OrderLots(),Bid,3);
               }
            }
                  
            if(OrderType()==OP_SELL)
            {  
            if(RSILocalMin <= (RSICurrent-4) && RSILocalMin<50)
               {
               OrderClose(OrderTicket(),OrderLots(),Ask,3);
               }
            }
            
         }
      }
}
return(0);
 
}
 
 
//=======================================================================
 
 
double RSIAreaFunc(int RSIAreaShift, double RSIPeriod, int BeginShift)
 
{
   
   int shift;
   double rsivalue, result;
   result = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, BeginShift) - 50.0;
   
   for(shift=BeginShift+1; shift<Bars-RSIPeriod; shift++)
   {
   rsivalue = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, shift) - 50.0;
      
      if((result>0 && rsivalue<-3) || (result<0 && rsivalue>3))
         {
         RSIAreaShift=shift;
         break;
         }
         
      result += rsivalue;
   }
   return(result);
}

Ошибки исправил, те что нашел, но сделки почему-то не закрываются:(

В тексте книги в этом месте ошибки набора. Вот оригинал эксперта

//+------------------------------------------------------------------+
//|                                                     RSI_Area.mq4 |
//|                      Copyright © 2005, MetaQuotes Software Corp. |
//|                                        https://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2005, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net/"
 
extern int RSIPeriod=13;
extern int AreaCondition=300;
double RSIArea, RSIOpen;
//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+
int start()
  {
   static int RSIAreaShift=0;
   int    cnt, shift;
   double RSICurrent, RSILocalMin, RSILocalMax, value;
//---- 
   if(OrdersTotal()<1)
     {
      RSIArea = RSIAreaFunc(RSIAreaShift, RSIPeriod, 0);
      //---- проверяем на возможность встать в длинную позицию
      if(RSIArea<-AreaCondition)
        {
         OrderSend(Symbol(),OP_BUY,1.0,Ask,3,0.0,0.0);
         RSIOpen = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
         return(0);
        }
      //---- проверяем на возможность встать в короткую позицию
      if(RSIArea>AreaCondition)
        {
         OrderSend(Symbol(),OP_SELL,1.0,Bid,3,0.0,0.0);
         RSIOpen = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
         return(0);
        }
      RSIAreaShift=0;
     }
   RSICurrent = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
   if(RSIOpen>50 && RSICurrent>50) return(0);
   if(RSIOpen<50 && RSICurrent<50) return(0);
 
   RSILocalMin = RSICurrent;
   RSILocalMax = RSICurrent;
   for(shift=1; shift<RSIAreaShift; shift++)
     {
      value = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, shift);
      if(value<RSILocalMin && RSIArea>0) RSILocalMin=value;
      if(value>RSILocalMax && RSIArea<0) RSILocalMax=value;
     }
 
   for(cnt=OrdersTotal()-1; cnt>=0; cnt--)
     {
      OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
      if(OrderSymbol()==Symbol())
        {
         if(OrderType()==OP_BUY)
           {
            //---- проверим, может уже пора закрываться?
            if(RSILocalMax>=RSICurrent+4 && RSILocalMax>50)
               OrderClose(OrderTicket(),OrderLots(),Bid,3);
           }
         if(OrderType()==OP_SELL)
           {
            if(RSILocalMin<=RSICurrent-4 && RSILocalMin<50)
               OrderClose(OrderTicket(),OrderLots(),Ask,3);
           }
        }
     }
//----
   return(0);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double RSIAreaFunc(int& RSIAreaShift, double RsiPeriod, int BeginShift)
  {
   int    shift;
   double rsivalue, result;
 
   result = iRSI(NULL, 0, RsiPeriod, PRICE_CLOSE, BeginShift) - 50.0;
   for(shift=BeginShift+1; shift<Bars-RsiPeriod; shift++)
     {
      rsivalue = iRSI(NULL, 0, RsiPeriod, PRICE_CLOSE, shift) - 50.0;
      if((result>0 && rsivalue<-3) || (result<0 && rsivalue>3))
        {
         RSIAreaShift=shift;
         break;
        }
      result += rsivalue;
     }
   return(result);
  }
//+------------------------------------------------------------------+

А вот оригинал индикатора

//+------------------------------------------------------------------+
//|                                             RSIAreaIndicator.mq4 |
//|                      Copyright © 2005, MetaQuotes Software Corp. |
//|                                        https://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2005, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net/"
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Gray
#property indicator_color2 Gray
//---- input parameters
extern int       ExtRSIPeriod=13;
//---- buffers
double ExtMapBuffer1[];
double ExtMapBuffer2[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   IndicatorShortName("RSIArea("+ExtRSIPeriod+")");
//---- indicators
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0,ExtMapBuffer1);
   SetIndexStyle(1,DRAW_HISTOGRAM);
   SetIndexBuffer(1,ExtMapBuffer2);
   SetIndexLabel(1,NULL);
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int counted_bars=IndicatorCounted();
//---- last counted bar will be recounted
   if(counted_bars>0) counted_bars--;
   int limit=Bars-counted_bars;
//---- macd counted in the 1-st additional buffer
   for(int i=0; i<limit; i++)
     {
      double value=iRSI(NULL,0,ExtRSIPeriod,PRICE_CLOSE,i)-50.0;
      ExtMapBuffer1[i]=value;
      ExtMapBuffer2[i]=value;
     }
//----
   return(0);
  }
//+------------------------------------------------------------------+

ну вот:) а я исправлял, старался:)

Вот исправленный, работает:

//+------------------------------------------------------------------+
//|                                                 RSI-AREA.mq4     |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       https://www.metaquotes.net// |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link      "https://www.metaquotes.net//"
 
extern int RSIPeriod=13;
extern int AreaCondition=300;
double RSIArea,RSIOpen;
int init() {return(0);}
int deinit() {return(0);}
double RSIAreaFunc(int& RSIAreaShift, double RSIPeriod, int BeginShift)
 {
  int shift;
  double rsivalue, result; 
  result = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, BeginShift) - 50.0;
  for(shift=BeginShift+1; shift<Bars-RSIAreaShift; shift++)
   {
    rsivalue = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, shift) - 50.0;
    if((result>0 && rsivalue<-3) || (result<0 && rsivalue>3))
     {
      RSIAreaShift=shift;
      break;
     }
    result += rsivalue;
   }
  return(result);
 }
// 
int start()
 {
  static int RSIAreaShift=0;
  int cnt, shift;
  double RSICurrent, RSILocalMin, RSILocalMax, value;
//--
  if(OrdersTotal()<1)
   {
    RSIArea = RSIAreaFunc(RSIAreaShift, RSIPeriod, 0);
    if(RSIArea<-AreaCondition)
     {
      OrderSend(Symbol(),OP_BUY,1.0,Ask,3,0.0,0.0);
      RSIOpen = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
     }
    if(RSIArea>AreaCondition)
     {
      OrderSend(Symbol(),OP_SELL,1.0,Bid,3,0.0,0.0);
      RSIOpen = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
      return(0);
     }
//    
   }
  RSICurrent = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, 0);
  if(RSIOpen>50 && RSICurrent>50) return(0);
  if(RSIOpen<50 && RSICurrent<50) return(0);      
  RSILocalMin = RSICurrent;
  RSILocalMax = RSICurrent;
  for(shift=1; shift<RSIAreaShift; shift++)
   {
    value = iRSI(NULL, 0, RSIPeriod, PRICE_CLOSE, shift);
    if(value<RSILocalMin && RSIArea>0) RSILocalMin=value;
    if(value>RSILocalMax && RSIArea<0) RSILocalMax=value;   
    for(cnt=OrdersTotal()-1; cnt>=0; cnt--)
     {
      OrderSelect(cnt,SELECT_BY_POS,MODE_TRADES);
      if(OrderSymbol()==Symbol())
       {
        if(OrderType()==OP_BUY)
         {
          if(RSILocalMax>=RSICurrent+4 && RSILocalMax>50)OrderClose(OrderTicket(),OrderLots(),Bid,3);
         }
        if(OrderType()==OP_SELL)
         {
          if(RSILocalMin<=RSICurrent-4 && RSILocalMin<50)OrderClose(OrderTicket(),OrderLots(),Ask,3);
         }
       }
     }
   }    
  return(0);
 }

Ещё один? :о

Даже не очень-то и сливает))))))




Strategy Tester: RSI-Area

В Вашем оригинале явная ошибка. Нужно так:for(shift=BeginShift+1; shift<Bars-RSIAreaShift; shift++)

пожалуйста объясните как правильно тестить у меня в тестере никаких графиков изменения баланса нет вообще ничего нет!