Навигатор по форуму и ответы на часто задаваемые вопросы. Настоятельно Рекомендуется к Прочтению! - страница 2

Новый комментарий
 

стр2

Как сделать, чтобы при тестировании в режиме визуализации на график автоматически устанавливались нужные индикаторы?

sergeev: Для этого необходимо создать шаблон с именем tester.tpl
  • Разместить на чарте все требуемые индикаторы, настроить цвет и остальные свойства чарта.

 

  • Затем в контекстном меню чарта выбрать пункт Шаблон->Сохранить шаблон...
    Сохранить шаблон с именем tester.tpl .



Если назвать шаблон именем тестируемого советника, то этот шаблон будет автоматически вызываться при прогоне одноименного советника.

Единственным недостатком шаблонов является невозможность автоматически изменять параметры установленных индикаторов. Придётся вручную изменять их в соответствии с установками советника.

 


С чего начать новичку?

Figar0: MetaTrader (МТ) компании «MetaQuotes Software Corp.» это бесплатная программа для интернет-трейдинга, технического анализа финансовых рынков, разработки и использования автоматических торговых систем. На текущий момент, существуют две версии МТ: MetaTrader 4 и MetaTrader 5, являющаяся развитием версии 4. Далее по тексту речь пойдет о 4й версии программы (МТ4).

МТ4 может быть бесплатно скачен и установлен с сайтов компаний,предоставляющих услуги интернет-трейдинга и использующих данную торговую платформу. Можно скачать МТ4 непосредственно с сайта разработчика программы. Так же существуют версии MetaTrader для ряда мобильных платформ, эта версия обладает несколько урезанным функционалом по сравнению с версией для ПК.

МТ4 состоит из трех основных модулей:

  • Торговый терминал. Основные функции: совершение торговых операций, протоколирование торговых операций и событий, управление торговыми счетами и т.д.
  • Тестер стратегий. Используется для тестирования торговых стратегий.
  • Редактор Metaeditor.Используется для создания инструментов технического анализа, обработки данных и автоматизированных торговых систем на языке MQL4.

Язык MQL4 позволяет значительно расширить возможности MT4. MQL4 достаточно прост для изучения даже людьми без опыта программирования. В помощь начинающим изучать язык накоплено множество материалов, существует сайт технической поддержки МТ4/MQL4 MQL4.community, где есть:

  • Учебник языка MQL4. Именно с этого пособия рекомендуется начинать изучение языка людям не имеющим навыков программирования и желающих самостоятельно научиться программировать на MQL4.
  • Статьи. Более 200статей касающихся различных аспектов использования МТ4, написания программ на языке MQL4 и просто трейдинга. Статьи написаны разными авторами, расcчитаны на разный уровень подготовки читателя, и могут быть интересны широкой аудитории. Начинающим изучать язык, в первую очередь, могут быть интересны статьи серии «Язык MQL4 для "чайников"»:
    - Первое знакомство
    - Сложные вопросы простым языком
    - Технические индикаторы и встроенные функции
    - Пользовательские индикаторы (часть 1 и 2)
  • Базу кодов программ на языке MQL4,содержащую более 2700 программ (скриптов, библиотек, индикаторов и советников) готовых к использованию. Могут послужить наглядным примером для изучения языка людьми уже имеющими навыки программирования.
  • Справочник языка MQL4. Незаменимый помощник при написании любых программ на MQL4.
  • Обзор базовых средств технического анализа финансовых рынков, так же содержит описание всех встроенных в терминал технических индикаторов.
  • Форум. Основной элемент онлайн поддержки пользователей. Здесь Вы сможете найти ответ на любой вопрос касательно работы МТ4, языка MQL4 и много другой полезной информации. Для быстрого и удобного доступа к интересующей Вас информации на форуме есть FAQ (структурированная подборка ответов на наиболее часто задаваемые вопросы), так же рекомендуется воспользоваться поиском по форуму и другим разделам сайта. В случае, если интересующий вас ответ не удается найти, зарегистрировавшись на сайте (обязательно внимательно прочтите правила форума), Вы всегда можете задать свой вопрос. Для получения быстрого и правильного ответа,выберите наиболее подходящую для этого ветку форума, например Вопросы новичков или создайте новую. Постарайтесь максимально подробно описать проблему, при необходимости снабдив ее картинками, логами терминала, кодами программ.

Если у Вас нет желания изучать MQL4 Вы можете воспользоваться услугами профессиональных программистов (предварительно рекомендуется ознакомиться со статьей «Как заказать написание советника и получить желаемый результат» ).

 


Как получить сигнал пересечения двух МА?

sergeev: Самый простой способ - это взять значения двух требуемых МА и посмотреть на их расположение.

Если на текущем баре МА1 будет выше МА2, а на предыдущем баре МА1 ниже МА2 - это значит, что МА1 пересекла МА2 снизу вверх.
И аналогично в обратном случае. Если на текущем баре МА1 будет ниже МА2, а на предыдущем баре МА1 выше МА2 - это значит, что МА1 пересекла МА2 сверху вниз.

Например быстрая МА - это EMA, периодом с 10, по цена закрытия, медленная МА тоже EMA c периодом 20, по ценам закрытия.
В коде это будет выглядеть следующим образом:

// берем два соседних значения Быстрой МА
double fast0=iMA(Symbol(), Period(), 10, 0, MODE_EMA, PRICE_CLOSE, 0);
double fast1=iMA(Symbol(), Period(), 10, 0, MODE_EMA, PRICE_CLOSE, 1);
 
// берем два значения Медленной МА
double slow0=iMA(Symbol(), Period(), 20, 0, MODE_EMA, PRICE_CLOSE, 0);
double slow1=iMA(Symbol(), Period(), 20, 0, MODE_EMA, PRICE_CLOSE, 1);
 
// сравниваем значения и определяем направление пересечения
if (fast0>slow0 && fast1<slow1) Print("Пересечение ВВЕРХ");
if (fast0<slow0 && fast1>slow1) Print("Пересечение ВНИЗ");


пример отдельной функции CheckCrossMA:

Функция принимает: требуемый символ, таймфрейм и бар, с которого необходимо получить данные.
Функция возвращает:
OP_BUY - если быстрая пересекает медленную снизу вверх,
OP_SELL - если быстрая пересекает медленную сверху внизу,
-1 - если нет пересечения.

Параметры МА (период, метод, цена) вынесены в глобальные. 

// параметры быстрой МА
int fPeriod=10; // период
int fMode=MODE_EMA; // метод расчета
int fPrice=PRICE_CLOSE; // цену для расчета
 
// параметры медленной МА
int sPeriod=20; // период
int sMode=MODE_EMA; // метод расчета
int sPrice=PRICE_CLOSE; // цену для расчета
 
//------------------------------------------------------------------    CheckCrossMA
int CheckCrossMA(string smb, int tf, int i)
{
  // берем два значения Быстрой МА
  double fast0=iMA(smb, tf, fPeriod, 0, fMode, fPrice, i);
  double fast1=iMA(smb, tf, fPeriod, 0, fMode, fPrice, i+1);
  
  // берем два значения Медленной МА
  double slow0=iMA(smb, tf, sPeriod, 0, sMode, sPrice, i);
  double slow1=iMA(smb, tf, sPeriod, 0, sMode, sPrice, i+1);
  
  // сравниваем значение и определяем пересечение
  if (fast0>slow0 && fast1<slow1) return(OP_BUY); // пересечение вверх
  if (fast0<slow0 && fast1>slow1) return(OP_SELL); // пересечение вниз
  return(-1); // иначе нет сигнала
}


пример использования функции для открытия ордера: 

int dir=CheckCrossMA(Symbol(), Period(), 1); // анализируем пересечение на закрытом баре
if (dir==-1) return; // если нет пересечения, то выходим
 
double op; // переменная для цены открытия 
if (dir==OP_BUY) op=Ask; // если пересечение вверх (сигнал BUY)
if (dir==OP_SELL) op=Bid; // если пересечение вниз (сигнал SELL)

 
OrderSend(Symbol(), dir, 1, op, 0, 0, 0); // открываем ордер по этому сигналу


пример использования функции в индикаторе:

//+------------------------------------------------------------------+
//|                                                         MA_Cross |
//|                                   Copyright © 2011, Alex Sergeev |
//|                                              profy.mql@gmail.com |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2011, Alex Sergeev"
#property link      "profy.mql@gmail.com"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_color1 LimeGreen
#property indicator_color2 Red
#property indicator_width1 2
#property indicator_width2 2
 
// параметры быстрой МА
extern int fPeriod=10; // период
extern int fMode=MODE_EMA; // метод расчета
extern int fPrice=PRICE_CLOSE; // цену для расчета
 
// параметры медленной МА
extern int sPeriod=20; // период
extern int sMode=MODE_EMA; // метод расчета
extern int sPrice=PRICE_CLOSE; // цену для расчета

 
double UpCrossing[], DnCrossing[]; // буферы для значков пересечения МА
//------------------------------------------------------------------  init
int init()
{
  // задаем свойства буферов
  SetIndexBuffer(0, UpCrossing); SetIndexStyle(0, DRAW_ARROW); SetIndexArrow(0, SYMBOL_ARROWUP);
  SetIndexBuffer(1, DnCrossing); SetIndexStyle(1, DRAW_ARROW); SetIndexArrow(1, SYMBOL_ARROWDOWN);
  return(0);
}
//------------------------------------------------------------------  start
int start()
{  
  int count=IndicatorCounted(); if (count<0) return;
  if (count>0) count--;
  for(int i=Bars-count-1; i>=0; i--)
  {
    int dir=CheckCrossMA(Symbol(), Period(), i); // вызываем функцию определения пересечения

    
    if (dir==OP_BUY) UpCrossing[i]=High[i]; // если функция вернула пересечение ВВЕРХ
    if (dir==OP_SELL) DnCrossing[i]=Low[i]; // если функция вернула пересечение ВНИЗ
  }
  return(0);
}
//------------------------------------------------------------------  CheckCrossMA
int CheckCrossMA(string smb, int tf, int i)
{
  // берем два значения Быстрой МА
  double fast0=iMA(smb, tf, fPeriod, 0, fMode, fPrice, i);
  double fast1=iMA(smb, tf, fPeriod, 0, fMode, fPrice, i+1);

  
  // берем два значения Медленной МА
  double slow0=iMA(smb, tf, sPeriod, 0, sMode, sPrice, i);
  double slow1=iMA(smb, tf, sPeriod, 0, sMode, sPrice, i+1);

  
  // сравниваем значение и определяем пересечение
  if (fast0>slow0 && fast1<slow1) return(OP_BUY); // пересечение вверх
  if (fast0<slow0 && fast1>slow1) return(OP_SELL); // пересечение вниз
  
  return(-1); // иначе нет сигнала
}
Прикрепленные файлы:
Check2MAsCrossing.mq4 (4.01 KB) удалить
 

Как проверить пересечение МА с учетом требуемого расхождения?

VladislavVG: Для этого как и в первом варианте необходимо найти само пересечение, а затем опреелить на сколько разошлись МА друг от друга.
Тонкостью является необходимость исключения случая касания мувингов без последующего их пересечения.

пример отдельной функции CheckCrossMADist:

Функция принимает:
- требуемый символ, таймфрейм и бар, с которого необходимо получить данные.
- и параметр dist - минимальное требуемое расстояние пересечение для его фиксации

Функция возвращает:
0 - при отсутствии смены знака разности
или величину разности на исследуемом баре.
"+" - быстрый мувинг находится над медленным
"-" - быстрый мувинг под медленным

Параметры МА (период, метод, цена) вынесены в глобальные.

double CheckCrossMADist(string smb, int tf, int iB, double dist)
{
  double dMA=iMA(smb, tf, fPeriod, 0, fMode, fPrice, iB)-iMA(smb, tf, sPeriod, 0, sMode, sPrice, iB);
  if (MathAbs(dMA)<dist*Point) return(0); // если разница меньше порога, то пересечения нет
  
  int n=iBars(smb, tf)-MathMax(sPeriod, fPeriod)-1; // число баров для проверки (c учетом корректности расчета МА)
  for(int i=iB+1; i<n; i++) // проходим по барам
  {
    double dMA2=iMA(smb, tf, fPeriod, 0, fMode, fPrice, i)-iMA(smb, tf, sPeriod, 0, sMode, sPrice, i);
    if(MathAbs(dMA2)>=dist*Point) break; // если нашли расстояние больше порога, то обрываем поиск
  }
  if (dMA*dMA2>0) return(0); // проверяем знак разниц. если одинаковый, то пересечение не найдено
  return(dMA); // вернули знак пересечения
}

пример использования функции в индикаторе: 

//+------------------------------------------------------------------+
//|                                                      MACrossDist |
//|                        Copyright © 2011, VladislavVG (VG,VladVG) |
//|                                                   4vg AT mail.ru |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2011, VladislavVG (VG, VladVG)"
#property link      "4vg AT mail.ru"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_color1 LimeGreen
#property indicator_color2 Red
#property indicator_width1 2
#property indicator_width2 2
 
// параметры быстрой МА
extern int fPeriod=10; // период
extern int fMode=MODE_EMA; // метод расчета
extern int fPrice=PRICE_CLOSE; // цену для расчета
 
// параметры медленной МА
extern int sPeriod=20; // период
extern int sMode=MODE_EMA; // метод расчета
extern int sPrice=PRICE_CLOSE; // цену для расчета
 
extern int MinDist=5; // минимальное расстояние расхождения для фиксации пересечения
 
double UpCrossing[], DnCrossing[]; // буферы для значков пересечения МА
//------------------------------------------------------------------  init
int init()
{
  // задаем свойства буферов
  SetIndexBuffer(0, UpCrossing); SetIndexStyle(0, DRAW_ARROW); SetIndexArrow(0, SYMBOL_ARROWUP);
  SetIndexBuffer(1, DnCrossing); SetIndexStyle(1, DRAW_ARROW); SetIndexArrow(1, SYMBOL_ARROWDOWN);
  return(0);
}
//------------------------------------------------------------------  start
int start()
{  
  int count=IndicatorCounted(); if (count<0) return;
  if (count>0) count--;
  for(int i=Bars-count-1; i>=0; i--)
  {
    double dist=CheckCrossMADist(Symbol(), Period(), i, MinDist); // вызываем функцию определения пересечения
    if (dist>0) UpCrossing[i]=High[i]; // если функция вернула пересечение ВВЕРХ
    if (dist<0) DnCrossing[i]=Low[i]; // если функция вернула пересечение ВНИЗ
  }
  return(0);
}
//------------------------------------------------------------------  CheckCrossMADist
double CheckCrossMADist(string smb, int tf, int iB, double dist)
{
  double dMA=iMA(smb, tf, fPeriod, 0, fMode, fPrice, iB)-iMA(smb, tf, sPeriod, 0, sMode, sPrice, iB);
  if (MathAbs(dMA)<dist*Point) return(0); // если разница меньше порога, то пересечения нет
  
  int n=iBars(smb, tf)-MathMax(sPeriod, fPeriod)-1; // число баров для проверки (c учетом корректности расчета МА)
  for(int i=iB+1; i<n; i++) // проходим по барам
  {
    double dMA2=iMA(smb, tf, fPeriod, 0, fMode, fPrice, i)-iMA(smb, tf, sPeriod, 0, sMode, sPrice, i);
    if(MathAbs(dMA2)>=dist*Point) break; // если нашли расстояние больше порога, то обрываем поиск
  }
   
  if (dMA*dMA2>0) return(0); // проверяем знак разниц. если одинаковый, то пересечение не найдено
  return(dMA); // вернули знак пересечения
}

теги: iMA, MODE_EMA, PRICE_CLOSE, пользовательские индикаторы

смотрите также:
Как получить сигнал пересечения двух МА

 


Как оформить пост, вставить код программы, изображение, видео

Для работы с текстами на Форуме, в Статьях и в Code Base используется единая среда редактирования с удобным и интуитивно понятным интерфейсом. Рассмотрим его возможности.

  • Кнопка переключает редактор из визуального режима в режим HTML. При нахождении в режиме HTML название кнопки меняется на и при нажатии возвращает редактор в визуальный режим. Данная функция позволяет придать вашему тексту максимально структурированный и красиво оформленный вид.
  • Кнопки (Ctrl+Z) и (Ctrl+Y) предназначены, соответственно, для отмены последнего действия и для повтора последнего отмененного действия.
  • Кнопка предназначена для создания маркированного списка (каждый пункт будет начинаться с маркера).
  • Кнопка предназначена для создания нумерованного списка (каждому пункту будет присвоен порядковый номер).
  • Кнопка предназначена для понижения иерархического положения элемента списка.
  • Кнопка предназначена для повышения иерархического положения элемента списка.
  • Кнопка (Ctrl+H) предназначена для вставки в текст разделителя в виде горизонтальной линии.

  • Кнопка (Ctrl+Alt+L) предназначена для добавления ссылок в текст сообщения. При нажатии появляется одноименное окно, изображенное на рисунке ниже.


    В поле Ссылка необходимо ввести адрес ссылки, а затем нажать кнопку Вставить.

  • Кнопка (Ctrl+Alt+I) предназначена для вставки картинки в сообщение. При нажатии на эту кнопку появляется окно, изображенное на рисунке ниже.


    В поле Загрузить изображение необходимо указать файл картинки. Для этого необходимо нажать кнопку Обзор, которая открывает стандартное окно выбора файлов. Следует указать нужный файл и нажать Вставить для завершения выбора, либо Отмена для прерывания операции. В поле Заголовок можно добавить комментарий к картинке, который будет отображаться в виде всплывающей подсказки при наведении курсора на картинку.

    В режиме HTML запрещается вставлять ссылки на изображения с внешних ресурсов (HTML-тэг "src"). Также запрещается копировать в редактор текст, содержащий такие изображения.

    При сохранении текста, содержащего ссылки на изображения с внешних ресурсов, такие ссылки будут автоматически удалены. Это сделано для обеспечения безопасности участников MQL5.Community.

  • Кнопка (Ctrl+Alt+T) предназначена для добавления в текст таблиц. При нажатии на нее появляется окно Таблица, изображенное ниже.


    Для создания таблицы необходимо заполнить несколько полей:

    • Колонки - количество колонок в таблице
    • Строки - количество строк в таблице
    • Стиль - выбор стиля таблицы. Предусмотрены три варианта: Стандартная и Без границ и Без заголовка. Для выбора нужного варианта необходимо нажать левой кнопкой мыши на кнопку с изображением стрелки вниз в конце строки. Далее - выбрать нужный стиль таблицы.
    • Ширина - ширина таблицы в процентах от размера окна сообщения.
    • Высота - высота таблицы в пикселях.
    • Отступ в ячейках - отступ между текстом и границами ячеек внутри таблицы.

    В правой части окна под полем Стиль расположено окно предварительного просмотра таблицы. Для добавления таблицы необходимо нажать кнопку Вставить, для отмены операции - Отмена.

  • Кнопка предназначена для вставки исходного кода MQL в текст сообщения. При нажатии появляется пустое окно, в которое необходимо вставить код и далее нажать кнопку Вставить. Для отмены вставки кода необходимо нажать кнопку Отмена. Не рекомендуется выделять код полужирным шрифтом, чтобы выделить как-то по смыслу определенные куски. Дело в том, что в разных операционных системах и браузерах моноширинные шрифты отображаются по разному. Например, в Windows Vista используется моноширинный шрифт Consolas, у которого полужирное начертание для 10 размера практически не отличимо от обычного.

  • Кнопка предназначена для вставки в ваше сообщение видеороликов. При нажатии на данную кнопку появляется окно, изображенное на рисунке ниже:


    В окне присутствуют две опции: Вставить HTML код и Загрузить видео в формате *.FLV. Первая предназначена для вставки видеороликов из YouTube, Google Video, RuTube и других видеосервисов. Для этого в окно необходимо вставить код видеоролика, скопировав его с соответствующего ресурса. Опция Загрузить видео в формате *.FLV предназначена для непосредственной загрузки видеофайлов в формате FLV. Для выбора загружаемого файла нажмите кнопку Обзор и далее Вставить, для отмены нажмите Отмена.

  • Поле Стиль (по умолчанию - обычный) предназначено для изменения стиля текста. При нажатии кнопки с изображением стрелки вниз появляется выпадающий список. Доступные варианты: обычный, заголовок, цитата, предупреждение, код, зачеркнуто, важно, маленький.
  • Кнопка (Ctrl+B) - выделение текста жирным шрифтом
  • Кнопка (Ctrl+I) - выделение текста курсивом
  • Кнопка (Ctrl+U) - подчеркивание текста
  • Кнопка - изменение цвета текста. Нажмите на стрелку, расположенную в правой части кнопки - появится окно с набором цветов. Для выбора цвета текста нужно просто нажать левой кнопкой мыши на нужный цвет.
  • Кнопка - изменение цвета фона под текстом. Выбор цвета фона происходит по той же схеме, что и выбор цвета шрифта.
  • Группа кнопок выравнивания текста: По левому краю (Ctrl+L), По центру (Ctrl+E), По правому краю (Ctrl+R) и По ширине (Ctrl+J). Для выравнивания необходимо выделить нужный фрагмент текста и нажать одну из четырех кнопок.
  • Кнопка - отмена форматирования всего текста стилями.


    смотрите также:
    Не могу прикрепить файл к своему посту. В чем может быть проблема?

 


Не могу прикрепить файл к своему посту. В чем может быть проблема?

TheExpert: причин может быть две:

1) превышен допустимый размер файла. Необходимо заархивировать в zip архив или разбить на части, размером не превышающие 4 МБ .

2) недопустимое расширение. Необходимо заархивировать в zip архив, изменить расширение на допустимое ( mq4, ex4, mq5, ex5, mqh, mqt, zip, txt ).

смотрите также:
Как оформить пост, вставить код программы, изображение, видео

 

Как установить индикатор, скрипт, библиотеку dll, шаблон tpl ?

AM2 :

Как установить индикатор?

  1. Откройте в папку, где расположен терминал (например в C:\Program Files\MetaTrader4 )
  2. Скопируйте файл индикатора (ex4 или mq4) в каталог MetaTrader4\experts\indicators .
  3. Перезапустите торговый терминал.
  4. В терминале в окне Навигатор->Пользовательские Индикаторы вы увидите индикатор который Вы добавили в торговый терминал.
  5. Активация индикатора: перенесите его мышью из Навигатора на график необходимой пары.

Как установить скрипт?

  1. Откройте в папку, где расположен терминал (например в C:\Program Files\MetaTrader4 )
  2. Скопируйте фаил скрипта (ex4 или mq4) в каталог MetaTrader4\experts\scripts
  3. Перезапустите торговый терминал.
  4. В терминале в окне Навигатор->Скрипты вы увидите добавленный скрипт.
  5. Запуск скрипта: перенесите его мышью из Навигатора на график необходимой пары.

Как установить файл библиотеки dll ?

  1. Откройте в папку, где расположен терминал (например в C:\Program Files\MetaTrader4 )
  2. Скопируйте файл библиотеки в каталог MetaTrader4\experts\libraries

Как установить шаблон tpl ?

  1. Откройте в папку, где расположен терминал (например в C:\Program Files\MetaTrader4 )
  2. Скопируйте файл шаблона в каталог MetaTrader4\templates .
  3. Активация шаблона: кликнуть правой кнопкой мыши на нужном торговом графике и в появившемся меню выбрать пункт «Шаблон » а затем нажать на нужный шаблон.
 


Как рассчитать стоимость пункта, маржу, результат операции?

AM2:

Расчёт стоимости 1 пункта:

  • Стоимость 1 пункта = минимальный шаг цены * торговый объём

Применяя данную формулу, помните, что стоимость 1 пункта, в результате расчёта всегда получается в валюте котировки, то есть в той валюте, которая находится в валютной паре справа.

Например:
Вы открыли позицию GBP/JPY объёмом 0.85 лот
Размер контракта = 100 000 GBP
Минимальный шаг цены = 0.01
Стоимость пункта = 0.85*100 000*0.01 = 850 JPY
Для перевода стоимости пункта в доллары, необходимо разделить на текущую котировку USD/JPY

Расчёт объёма маржи

  • Маржа (залог) = торговый объём / кредитное плечо

Например:
Вы открыли позицию GBP/USD объёмом 1.25 лот
Стандартный размер контракта 1 лот = 100 000 GBP
Кредитное плечо = 1:100
Текущая котировка GBP/USD = 1.6270
Маржа = 100 000 GBP / 100 = 1000 GBP
Для перевода маржи в доллары умножим на текущую котировку GBP/USD.
1000 GBP * 1.6270 = 1627 USD

Расчёт финансового результата торговой операции

  • Финансовый результат (BUY) = торговый объём * (цена закрытия - цена открытия)
  • Финансовый результат (SELL) = торговый объём * (цена открытия - цена закрытия)

Например:
Вы открыли BUY USD/CHF 1 лот.
Стандартный контракт (1лот) = 100 000 USD
Цена открытия = 1.1345
Цена закрытия = 1.1395
Фин. результат = 1*100000 * (1.1395 – 1.1345) = 500 CHF
Чтобы перевести в доллары необходимо разделить на текущий курс USD/CHF
500 / 1.1395 = 438 USD

 

Как установить в MetaTrader 4 советник?

AM2: Для правильной установки советника вам необходимо выполнить следующие действия:

  1. Откройте в папку, где расположен терминал (например в C:\Program Files\MetaTrader4)
  2. Скопируйте файл советника (ex4 или mq4 файл) в каталог MetaTrader4\experts
  3. Перезапустите торговый терминал.
  4. В терминале в окне Навигатор->Советники вы увидите советник который Вы добавили в торговый терминал (если советник серого цвета это означает что он имеет закрытый код и не имеет исходного кода для его модернизации).
  5. Запуск советника:
    Активируйте советник, перенеся его мышью из Навигатора на торговый график необходимой пары.
    Убедитесь, что в настройках советника на первой вкладке "Общие" ему разрешено торговать.



    А также в самом терминале кнопка "Советники" должна быть прижата



  6. Если Ваш советник использует библиотеки DLL, тогда необходимо установить галочку и напротив пункта «Разрешить импорт DLL».



    А сами файлы DLL поместить в папку MetaTrader4\experts\libraries
  7. В верхнем правом углу торгового графика должно появиться название советника и улыбающийся смайлик.



    Если смайлик не улыбается, то это означает, что не нажата кнопка "Советники" или ему запрещено торговать.
  8. Чтоб отключить советник, достаточно отжать кнопку "Советники".

ВНИМАНИЕ! При отсутствии советника на графике или выключенном терминале - он не активен! Терминал должен быть включен, и окно с советником должно быть открыто постоянно!

смотрите также:
Справка терминала F1

 

Как установить set-файл настроек советника?

AM2:

  1. В окне торгового графика с советником нажмите кнопку клавиатуры F7 или кликните правой кнопкой мыши и в появившемся окне нажмите на пункт «Советники» затем «Свойства».
  2. В открывшемся окне на вкладке «Входные параметры» нажмите на кнопку «Загрузить»



  3. Находите нужный файл настроек для советника и нажимаете «Открыть»
1234567
Новый комментарий
Причина обращения: