мол4 - MQL4 и MetaTrader 4 - Форум алго-трейдеров MQL4

Rustamzhan Salidzhanov 2010.06.21 18:48 #1

//+------------------------------------------------------------------+
//|                                                       _CLOSE.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2009, MetaQuotes Software Corp."
#property link      "http://www.metaquotes.net"

//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
//----
   for(int i=OrdersTotal();i>=0;i--){
     if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)){
       //if(OrderSymbol()==Symbol()){
         if(OrderType()<2){
           OrderClose(OrderTicket(),OrderLots(),NormalizeDouble(OrderClosePrice(),Digits),MarketInfo(Symbol(),MODE_DIGITS));
         }else{OrderDelete(OrderTicket());}
       //}
     }
   } 
//----
   return(0);
  }
//+------------------------------------------------------------------+

Alexander 2010.06.21 18:51 #2

Оно конечно и так сработает, но более корректно

for(int i=OrdersTotal()-1;i>=0;i--)

Rustamzhan Salidzhanov 2010.06.21 19:00 #3

а мне лень "-1" писать... если ордера с данным номером нет, то функция OrderSelect() и так не пропустит, а если уж быть совсем точным. то надо предварительно задать переменной значение OrdersTotal(), инваче постоянный вызов этой функции.

Глобальные переменные Любые вопросы новичков по Ошибки, баги, вопросы

DDFedor 2010.06.21 19:08 #4

почему мы не используем

   while(OrdersTotal()>0){// работаем до тех пор, пока не будут закрыты ВСЕ открытые ордера
      RefreshRates();

ведь в некоторых случаях эта конструкция более предпочтительна...

Alexander 2010.06.21 19:11 #5

В его случае OrderClosePrice() всегда новая.

Rustamzhan Salidzhanov 2010.06.21 19:21 #6

DDFedor:

почему мы не используем

ведь в некоторых случаях эта конструкция более предпочтительна...

до сих пор не знаю ..... как то так сложилось, что пользуемся пересчетом, просто while и позависнуть может... а так один проход, что не закрылось - я не виноват.... ессно все это примитив, по идее надо еще и проверять а закрылся ли ордер, и прочие предосторожности...

учитесь зарабатывать селяне [Эпизод FOREX - Тенденции, прогнозы Как определить последнюю цену

Alexander Sevastyanov 2010.06.21 21:37 #7

DDFedor:

почему мы не используем

   while(OrdersTotal()>0){// работаем до тех пор, пока не будут закрыты ВСЕ открытые ордера
      RefreshRates();

ведь в некоторых случаях эта конструкция более предпочтительна... ведь в некоторых случаях эта конструкция более предпочтительна...

По ТЗ требовалось закрыть ПОЗИЦИИ, а

OrdersTotal()

вернёт общее кол-во ордеров в т.ч. и отложенных.

Тут для корректности надо писать функцию подсчёта открытых позиций и на каждом проходе проверять.

Мой вариант скрипта:

//+------------------------------------------------------------------+
//|                                        ClosePositionByMarket.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
void start() {
   while (PositionsTotal() > 0) {
      ClosePositions();
   }
}
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//| Закрывает с рынка все открытые позиции                           |
//+---------------------------------------------------- -------------+
void ClosePositions() {
  for(int i=OrdersTotal()-1;i>=0;i--) {
    OrderSelect(i, SELECT_BY_POS);
    RefreshRates();
    if (OrderType()==OP_BUY) {
       OrderClose(OrderTicket(),OrderLots(),MarketInfo(OrderSymbol(),MODE_BID),5,0);
    }
    if (OrderType()==OP_SELL) {
       OrderClose(OrderTicket(),OrderLots(),MarketInfo(OrderSymbol(),MODE_ASK),5,0);
    }
  }
} 
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//    Функция, возвращающая сумманое количество позиций, открытых    |
//    советником по всем инструментам                                |
//+------------------------------------------------------------------+
int PositionsTotal() {
   int total = OrdersTotal(), pos = 0;
   for (int i = 0; i < total; i++) {
      OrderSelect(i, SELECT_BY_POS, MODE_TRADES);
      if (OrderType() == OP_BUY || OrderType() == OP_SELL)
         pos++;
   }
   return(pos);
}
//+------------------------------------------------------------------+

Vladislav Andruschenko 2010.06.22 06:24 #8

goldtrader:

По ТЗ требовалось закрыть ПОЗИЦИИ, а

вернёт общее кол-во ордеров в т.ч. и отложенных.

Тут для корректности надо писать функцию подсчёта открытых позиций и на каждом проходе проверять.

Мой вариант скрипта:

дык стоит же условие

if(OrderType()<2)

смысл писать отдельно функцию для проверки позиций ? :-)

Vladyslav Goshkov 2010.06.22 06:45 #9

Vladon:

дык стоит же условие

смысл писать отдельно функцию для проверки позиций ? :-)

Потому, что при наличии отложенных ордеров while в варианте дяди Федора попадет в бесконечный цикл.

2 DDFedor

почему мы не используем
   while(OrdersTotal()>0){// работаем до тех пор, пока не будут закрыты ВСЕ открытые ордера
      RefreshRates();
ведь в некоторых случаях эта конструкция более предпочтительна... ведь в некоторых случаях эта конструкция более предпочтительна...

Это самый медленный вариант: вызов функции на каждом проходе цикла, к тому же склонен к зацикливанию при наличии отложенных ордеров. while используют когда неизвестно максимальное количество проходов, а условие на выход формируется динамически. А так for и while полные аналоги.

2 xrust

xrust 21.06.2010 23:00
  

а мне лень "-1" писать... если ордера с данным номером нет, то функция OrderSelect() и так не пропустит, а если уж быть совсем точным. 
то надо предварительно задать переменной значение OrdersTotal(), инваче постоянный вызов этой функции.

В приведенном Вами варианте

for(int i=OrdersTotal();i>=0;i--)

не будет: условие перед первой ";" выполняется один раз - перед началом цикла. Зато такая привычка (опускать -1) запросто может привести к выходу за пределы массива (в других случаях). Потому лучше как в армии : "Безобразно, но однообразно" - легче ошибки вылавливать. ИМХО, естественно.

2 goldtrader

for(int i=OrdersTotal()-1;i>=0;i--) {
    OrderSelect(i, SELECT_BY_POS);

в общем случае не совсем верно: если ордер выбран не будет этот цикл все равно пытается его обработать. Более правильно :

for(int i=OrdersTotal()-1;i>=0;i--) 
{
    if(!OrderSelect(i, SELECT_BY_POS)) break;
.............................................
}

или так

for(int i=OrdersTotal()-1;i>=0;i--) 
    if(OrderSelect(i, SELECT_BY_POS))
    {
    ...................................
    }

Удачи.

Alexander Sevastyanov 2010.06.22 08:29 #10

VladislavVG:

2 goldtrader

в общем случае не совсем верно: если ордер выбран не будет этот цикл все равно пытается его обработать.

Согласен. Просто на практике не встречалось чтобы ордер не был выбран. С учётом Вашего замечания:

//+------------------------------------------------------------------+
//|                                        ClosePositionByMarket.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
void start() {
   while (PositionsTotal() > 0) {
      ClosePositions();
   }
}
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//| Закрывает с рынка все открытые позиции                           |
//+---------------------------------------------------- -------------+
void ClosePositions() {
   for(int i=OrdersTotal()-1;i>=0;i--) {
      if (OrderSelect(i, SELECT_BY_POS)) {
         RefreshRates();
         if (OrderType()==OP_BUY) {
            OrderClose(OrderTicket(),OrderLots(),MarketInfo(OrderSymbol(),MODE_BID),5,0);
         }
         if (OrderType()==OP_SELL) {
            OrderClose(OrderTicket(),OrderLots(),MarketInfo(OrderSymbol(),MODE_ASK),5,0);
         }
      }
   }
} 
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//    Функция, возвращающая сумманое количество позиций, открытых    |
//    советником по всем инструментам                                |
//+------------------------------------------------------------------+
int PositionsTotal() {
   int total = OrdersTotal(), pos = 0;
   for (int i = 0; i < total; i++) {
      if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
         if (OrderType() == OP_BUY || OrderType() == OP_SELL) {
            pos++;
         }
      }
   }
   return(pos);
}
//+------------------------------------------------------------------+