Самый мягко-агрессивный метод управления денюшкой (?) на микро/мини-Форексе

Вообще-то тема открыта рядом. Но в последнее время что-то слишком много появилось извечных Российских вопросов: "Что делать?", "Кто виноват?" и "Сколько времени мне понадобится, чтоб заработать свой первый миллиён?". А тема вроде хоть и неявно, но на них отвечает.

Ссылки на источники в шапке индюка, но поскольку по ссылкам ходить лениво, там же и процитировано, так что можно даже и не сёрчить.

Индикатор выводит в правый верхний угол графика размер лота для следующей позы с учетом того, что уже насотворено.

Нарисовал себе в табличку - вроде все разумно, вот и сваял индюка. Как пример - что встроить в советник и не думать.

//+------------+-----------------------------------------------------+
//| v.23.04.08 |                                    CalcLotsAFPM.mq4 |
//|            |              Bookkeeper, 2008, yuzefovich@gmail.com |
//+------------+-----------------------------------------------------+
/*-------------------------------------------------------------------+
   
   Первоисточник: 
   Райан Джонс, "Биржевая игра: Сделай миллионы, играя числами".
   Не читал, говорят - занудство жуткое.
   Источник, где разжевали: https://forum.mql4.com/ru/12080

   Цитирую с мизерными вольностями:
   Формула для расчета уровней возможного увеличения числа контрактов
   (лотов, опционов или акций) выглядит следующим образом:
   Капитал предыдущего уровня + (число контрактов х дельта) = следующий уровень
   Пример: 
   Начальный баланс =$10.000 (капитал первоначального уровня)
   Число контрактов = 1
   Дельта = $5.000 - величину задает трейдер сам. Дельта лежит в основе
   изменений. Это - единственная варьируемая константа в уравнении,
   которую пользователь свободно изменяет в соответствии со своим
   методом и/или стилем торговли. Также дельта может изменять динамику
   исхода. Общее правило такое: чем меньше дельта, тем более агрессивным
   может быть управление капиталом, а чем дельта больше, тем более
   консервативным становится метод. Итак:
   $10.000 + (1 х $5.000) = $15.000 необходимо, чтобы увеличить число
   контрактов на 1.
   Если баланс счета превысит 15.000 долларов, то $15.000 станет
   исходным требуемым уровнем в уравнении:
   $15.000 + (2 х $5.000) = $25.000
   и так далее:
   $25.000 + (3 х $5.000) = $40.000
   $40.000 + (4 х $5.000) = $60.000
   $60.000 + (5 х $5.000) = $85.000 и т.д.

   Добавлю от себя:
   Чем меньше уровень, тем более агрессивным будет управление капиталом,
   а чем уровень больше, тем более консервативным становится метод. Что
   не менее приятно:
   Есть возможность автоматического определения размера позы на
   микро/мини-Форексе, если первоисточник не врет - будет самый 
   мягко-агрессивный метод управления денюшкой :).
   
   Подставляем - максимум агрессивности:
   Начальный баланс =$300. 
   Число контрактов - читай: "число МинЛотов".
   Дельта - залог на 1 контракт (МинЛот).
   
   Получаем:

//+-----------------------------------------------------------------*/
#property copyright ""
#property link      ""
#property indicator_chart_window
//----
extern int depo=300;  // Минимальный размер средств для открытия
                     //  счета у Вашего брокера
// Если поставить depo=0 - получим самый агрессивный вариант
// управления капиталом (но изменения будут незначительные)
//----
bool first=true, firstAlert=true;
double MinLot, MaxLot;   
int NMinLotInMaxLot;
//+------------------------------------------------------------------+
int ObjectMakeLabel( string s, int x, int y )
{
   ObjectCreate( s, OBJ_LABEL, 0, 0, 0 );
   ObjectSet( s, OBJPROP_CORNER, 1 );
   ObjectSet( s, OBJPROP_XDISTANCE, x );
   ObjectSet( s, OBJPROP_YDISTANCE, y );
   ObjectSet( s, OBJPROP_BACK, true );
}
//+------------------------------------------------------------------+
void deinit() 
{
   ObjectDelete( "TL" );
   ObjectDelete( "L" );
   return; 
}
//---------------------------------------------------------------------
int init()
{
   ObjectMakeLabel("TL", 60, 25);
   ObjectMakeLabel("L", 15, 25);
   return(0);
}
//+------------------------------------------------------------------+
int start()
{
   string s;
   if(first==true)
   {
      // Минимальный и максимальный размеры лотов
      MinLot=MarketInfo(Symbol(),MODE_MINLOT);
      MaxLot=MarketInfo(Symbol(),MODE_MAXLOT);
      // Число МинЛотов в МаксЛоте
      NMinLotInMaxLot=MaxLot/MinLot;
   }
   double L=LotsAFPM();
   if(L<0) s="0.00";
   else s=DoubleToStr(L,2);
   ObjectSetText("TL", "Lots:", 10, "System", Blue);
   ObjectSetText( "L", s, 10, "System", Blue);
   return(0);
}
//---------------------------------------------------------------------
double LotsAFPM()
{
   // нужен залог на минлот
   double MarginMinLot=MarketInfo(Symbol(),MODE_MARGINREQUIRED)*MinLot;
   // имеем свободных средств
   double FreeMargin=AccountFreeMargin();
   // если их не имеем :(
   if(MarginMinLot>FreeMargin) return(-1.0);
   // а если имеем, то сколько лотов можем себе позволить на позу
   if(depo<MarginMinLot) depo=MarginMinLot;
   int n=1;
   int m=NMinLotInMaxLot-1;
   double level=depo+MarginMinLot*n;
   while(level<FreeMargin && n<m)
   {
      n++;
      level=level+MarginMinLot*n;
   }
   double lots=MinLot*n;
   return(lots);
}
//---------------------------------------------------------------------

Дополнительной инфы много. Например: для перехода на следующий уровень надо набрать сейчас по EURUSD 160 пунктов. Т.е. только после этого размер позы можно будет увеличить на 0.01.

Вот и посчитайте, сикока времени Вам на это надо?