Как реализовать такой алгоритм?

1. Определить тип последней позиции.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает тип последней открытой позиции или -1               |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
int GetTypeLastOpenPos(string sy="", int mn=-1) {
  datetime t;
  int      i, k=OrdersTotal(), r=-1;
 
  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (mn<0 || OrderMagicNumber()==mn)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (t<OrderOpenTime()) {
            t=OrderOpenTime();
            r=OrderType();
          }
        }
      }
    }
  }
  return(r);
}

2. Определить цену открытия последней позиции.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Возвращает цену открытия последней открытой позиций.           |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//+----------------------------------------------------------------------------+
double PriceOpenLastPos(string sy="", int op=-1, int mn=-1) {
  datetime t;
  double   r=0;
  int      i, k=OrdersTotal();
 
  if (sy=="0") sy=Symbol();
  for (i=0; i<k; i++) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if (OrderSymbol()==sy || sy=="") {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (op<0 || OrderType()==op) {
            if (mn<0 || OrderMagicNumber()==mn) {
              if (t<OrderOpenTime()) {
                t=OrderOpenTime();
                r=OrderOpenPrice();
              }
            }
          }
        }
      }
    }
  }
  return(r);
}

3. Выставить лимитник функцией OrderSend().

Игорь. Продублируйте пож. выложенные функции в Вашу веточку 'Полезные функции от KimIV'

Хотелось бы, чтобы в одном месте сосредоточить всё. Многие из посетителей "сохраняют" ту вашу ветку....

Я, Иван, скопировал свои функции в чистый MQ4-файл и попробовал скомпилировать в метаэдиторе. Всё нормально. Нет никаких ошибок. Следовательно, одно из двух:
1. Вы неправильно (не полностью) скопировали мои функции в свой советник.
2. В коде Вашего советника присутствуют сиснтаксические ошибки.

Иван, я считаю это очень неприличным, просить кого-то разобраться в коде, в котором чёрт ногу сломит. Это всё равно, что кого-то постороннего просить прибраться в своей комнате после пьяного дебоша.

В том месте, в котором Вы пытаетесь использовать мою функцию, советник не всегда видит открытую позицию. Видимо, это особенности кэширования или многопоточности, я не знаю. Не разбираюсь в этом. Более менее достоверно использовать открытую позицию можно только на следующем тике после открытия. А Вы пытаетесь это сделать на том же тике, на котором её открываете.

В прицепе причёсанный код.