Форум

Ошибка в числе передаваемых параметров (очень распространенная у новичков):

double upsig = iCustom(NULL,0,"AMAstdev",9,2,30,2.0,1.0 , int mode, int shift); //с заданными параметрами

поиск по форуму с ключом "АМА" (лат. регистр) - там есть примеры получше.

         if (ddK > Filter) kAMAupsig[pos] = AMA; //есть восходящий тренд
            else kAMAupsig[pos] = 0; //нет восходящего тренда
         if (ddK < -Filter) kAMAdownsig[pos] = AMA; //есть нисходящий тренд
            else kAMAdownsig[pos] = 0; // нет нисходящего тренда

SetIndexEmptyValue(0,0.0);

//+------------------------------------------------------------------+
//|                                            AMAstdevKiriyenko.mq4 |
//|                                                        Kiriyenko |
//|                                    'Помогите исправить ошибку в самопальном индикаторе' |
//+------------------------------------------------------------------+
#property copyright "Kiriyenko"
#property link      "'Помогите исправить ошибку в самопальном индикаторе'"
 
#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1 LightGreen
#property indicator_width1 1
#property indicator_color2 Red
#property indicator_width2 2
#property indicator_color3 Blue
#property indicator_width3 2
 
//+------------------------------------------------------------------+
//| макроопределения                                                 |
//+------------------------------------------------------------------+
 
//---- строковые константы
#define INDICATOR_SHORT_NAME "AMAstdev"
#define MAIN "AMA line"
#define UP   "UpTrend point"
#define DOWN "DownTrend point"
 
//+------------------------------------------------------------------+
//| внешние переменные                                               |
//+------------------------------------------------------------------+
 
//---- периоды
extern int       periodAMA = 9;   //период расчёта к-та эффективности
extern double    nfast     = 2;   //период EMA для эффективного рынка
extern double    nslow     = 30;  //период EMA для неэффективного рынка
 
//---- расчёт сглаживающей константы
extern double    Pow       = 2.0; //степень эффективности 
 
//---- влияние стандартного отклонения
extern double    dK        = 1.0; //коэффициент для фильтра
 
//+------------------------------------------------------------------+
//| глобальные переменные                                            |
//+------------------------------------------------------------------+
 
//---- буферы
double kAMAbuffer[];
double kAMAupsig[];
double kAMAdownsig[];
 
//---- оптимизация кода индикатора
int    cbars = 0, prevbars = 0, prevtime = 0;
 
//---- сглаживающие коэффициенты
double slowSC, fastSC;
 
//---- приращения индикатора
double ddAMA[];
 
//+------------------------------------------------------------------+
//| Вставка значения в массив приращений                             |
//+------------------------------------------------------------------+
bool InsertDif(double a)
  {
//---- проверка, заполнен ли массив
   for (int i = 0; i < periodAMA; i++) //для всех элементов массива
      if (ddAMA[i] == 0) //если элемент равен нулю
        {
         ddAMA[i] = a; //сохраняем значение в этот элемент
         return (true); //и удачно завершаемся
        }
//---- массив уже заполнен, нужно вставлять элемент с конца
   for (i = 0; i < periodAMA-1;i++) //все элементы массива, кроме последнего
      ddAMA[i] = ddAMA[i+1]; //сдвигаем влево на одну позицию
   ddAMA[periodAMA-1] = a; //и записываем значение в самую правую позицию
   return (true); //после чего удачно завершаемся
  }
 
//+------------------------------------------------------------------+
//| Инициализация                                                    |
//+------------------------------------------------------------------+
int init()
  {
//---- индикаторы
//---- главная линия
   SetIndexBuffer(0,kAMAbuffer);
   SetIndexStyle(0,DRAW_LINE,0,2);
   SetIndexLabel(0,MAIN);
//---- подтверждение восходящего тренда
   SetIndexBuffer(1,kAMAupsig);
   SetIndexStyle(1,DRAW_ARROW);
   SetIndexArrow(1,159);
   SetIndexLabel(1,UP);
//---- подтверждение нисходящего тренда
   SetIndexBuffer(2,kAMAdownsig);
   SetIndexStyle(2,DRAW_ARROW);
   SetIndexArrow(2,159);
   SetIndexLabel(2,DOWN);
//---- настройки индикатора
   IndicatorDigits(4);
   string name = StringConcatenate(INDICATOR_SHORT_NAME,
                                   " (",periodAMA,"/",nfast,"/",nslow,")");
   IndicatorShortName(name);
//---- расчёт к-тов    
   slowSC = (2.0 /(nslow+1)); //медленный к-т сглаживания
   fastSC = (2.0 /(nfast+1)); //быстрый к-т сглаживания
//---- подготовка массива
   ArrayResize(ddAMA,periodAMA);
   ArrayInitialize(ddAMA,0.);
//---- готово
   return(0);
  }
 
//+------------------------------------------------------------------+
//| Деинициализация                                                  |
//+------------------------------------------------------------------+
int deinit()
  {
   return(0);
  }
 
//+------------------------------------------------------------------+
//| Итерационная функция                                             |
//+------------------------------------------------------------------+
int start()
  {
//---- оптимизация производительности   
   double var1,var2;
 
   if (prevbars == Bars) return(0); //если индикатор уже посчитан, выходим 
   cbars = IndicatorCounted(); //к-во посчитанных баров
   if (Bars <= (periodAMA+2)) return(0); // если баров на графике
   if (cbars < 0) return(-1); //выходим при некорректном значении переменных
   if (cbars > 0) cbars--; //последний посчитанный бар будет пересчитан
//---- подготовка переменных
   int pos = Bars-cbars-periodAMA-2; //счётчик в начало периода
   double AMA0; //предыдущее AMA
   if (cbars == 0) AMA0 = Close[pos+1]; //предыдущее AMA не расчитывалось
//---- расчёт индикатора
   while (pos>=0)
     {
   //---- расчёт сигнала
      double signal = MathAbs(Close[pos]-Close[pos+periodAMA]); //трендовая составляющая
   //---- расчёт шума
      double noise = 0.000000001;
      for (int i = 0;i<periodAMA;i++)
        {
         noise = noise + MathAbs(Close[pos+i]-Close[pos+i+1]); //шумовая составляющая
        }
   //---- расчёт коэффициента сглаживания
      double ER = signal/noise; //коэффициент эффективности
      double SSC = ER*(fastSC-slowSC) + slowSC; //коэффициент сглаживания
   //---- расчёт главной линии
      double AMA = AMA0 + (MathPow(SSC,Pow)*(Close[pos]-AMA0)); //расчёт
      kAMAbuffer[pos]=AMA; //вывод
   //---- расчёт фильтрации тренда
      double ddK = (AMA - AMA0)/Point; //разность
      InsertDif(ddK); //накапливаем приращение
      if (pos < Bars - 2*(periodAMA+2)) //если баров накопилось достаточно
        {
      //---- расчёт среднего арифметического
         double SMAdif = 0; //вначале равно нулю
         for (i = 0; i < periodAMA; i++)
           {
            SMAdif += ddAMA[i]; //последовательно суммируем
           }
         SMAdif /= periodAMA; //и делим на количество
      //---- расчёт стандартного отклонения
         double StDev = 0; //вначале равно нулю
         for (i = 0; i < periodAMA; i++)
           {
            StDev += MathPow(ddAMA[i]-SMAdif,2); //суммируем квадраты отклонений
           }
         StDev = MathSqrt(StDev)/periodAMA; //извлекаем корень и делим на количество
      //---- расчёт фильтра
         double Filter = dK*StDev;
      //---- обработка значений
         var1=0;
         var2=0;
         if (ddK > Filter) var1=AMA; //есть восходящий тренд
         if (ddK < -Filter) var2=AMA; //есть нисходящий тренд
         kAMAupsig[pos] = var1; //нет восходящего тренда
         kAMAdownsig[pos] = var2; // нет нисходящего тренда
            
        }
   //---- переход к концу цикла
      AMA0 = AMA; //сохраняем предыдущее значение AMA
      pos--; //переходим к сдедующему бару
     }
//---- завершение работы
   prevbars=Bars; //сохраняем количество баров
   return(0); //готово
  }

//+------------------------------------------------------------------+
//|                                                 CheckAMAStep.mq4 |
//|                                                             Rosh |
//|                                    'Помогите исправить ошибку в самопальном индикаторе' |
//+------------------------------------------------------------------+
#property copyright "Rosh"
#property link      "'Помогите исправить ошибку в самопальном индикаторе'"
 
//+------------------------------------------------------------------+
//| script program start function                                    |
//+------------------------------------------------------------------+
int start()
  {
  double main,up,down;
//----
   for (int shift=100;shift>-0;shift--)
      {
      main=iCustom(Symbol(),0,"AMAstdevKiriyenko",9,2,30,2.0,1.0,0,shift);
      up=iCustom(Symbol(),0,"AMAstdevKiriyenko",9,2,30,2.0,1.0,1,shift);
      down=iCustom(Symbol(),0,"AMAstdevKiriyenko",9,2,30,2.0,1.0,2,shift);
      Print("i=","  main=",main,"  up=",up,"   down=",down);
      }
//----
   return(0);
  }
//+------------------------------------------------------------------+